// -- download mc_tween2 -> http://hosted.zeh.com.br/mctween/index.html
#include "mc_tween2.as"
Stage.scaleMode = "noScale";
Stage.align = "";
// --
var scroll_width:Number = 450;
var scroll_height:Number = 350;
var text_height:Number;
var xpos:Number = 50;
var ypos:Number = 20;
var container_level:Number = 1;
var text_level:Number = 2;
var mask_level:Number = 3;
var cursor_level:Number = 4;
var container_mc:MovieClip;
var mask_mc:MovieClip;
var text_txt;
var dragin:Boolean = false;
// --
var format:TextFormat = new TextFormat ();
format.align = "justify";
format.color = 0x000000;
format.font = "Verdana";
format.size = 10;
// -- instanciar clip de película cursor_mc
this.attachMovie ("cursor_mc", "cursor_mc", cursor_level, {_visible:false});
// -- animación cursor  mano, manejada por el evento onMouseMove
_root.onMouseMove = function () {
	// -- cursor mano solo si Mouse está en la zona de texto
       if (mask_mc.hitTest (_root._xmouse, _root._ymouse)) {
		// -- Mostrar cursor mano
		Mouse.hide ();
		cursor_mc._visible = true;
	} else if (!dragin) {
		// -- no mostrar cursor mano
		Mouse.show ();
		cursor_mc._visible = false;
	}
	// -- igualar _x/_y de cursor mano a _xmouse/_ymouse
	cursor_mc._x = _root._xmouse;
	cursor_mc._y = _root._ymouse;
	// -- refresco de pantalla(la animación es mas fluida)
	updateAfterEvent ();
};
// --
showScroll = function () {
	// -- clip contenedor
	container_mc = this.createEmptyMovieClip ("container_mc", container_level);
	// -- textfield
	text_txt = container_mc.createTextField ("text_txt", text_level, 0, 0, scroll_width, 10);
	container_mc.text_txt.type = "dynamic";
	container_mc.text_txt.selectable = false;
	container_mc.text_txt.wordWrap = true;
	container_mc.text_txt.autoSize = true;
	container_mc.text_txt.text = myLoadVars.texto;
	container_mc.text_txt.setTextFormat (format);
	text_height = container_mc.text_txt._height;
	// -- _x/_y inciales para container_mc
	container_mc._x = xpos;
	container_mc._y = text_height;
};
// -- Crea una máscara que permite visualizar la cantidad de
// -- texto especificada por la altura del clip de película mask_mc
maskScroll = function () {
	mask_mc = this.createEmptyMovieClip ("mask_mc", mask_level);
	with (mask_mc) {
		beginFill (0x000000, 100);
		moveTo (xpos, ypos);
		lineTo (xpos + scroll_width, ypos);
		lineTo (xpos + scroll_width, ypos + scroll_height);
		lineTo (xpos, ypos + scroll_height);
		lineTo (xpos, ypos);
		endFill ();
	}
	container_mc.setMask (mask_mc);
};
// -- Drag
dragScroll = function () {
	container_mc.onPress = function () {
		// -- esta variable permite que se muestre e cursor mano si True
		dragin = true;
		if (mask_mc.hitTest (_root._xmouse, _root._ymouse)) {
			// -- estado de cursor mano en arrastrar
			cursor_mc.gotoAndStop ("drag");
			container_mc.startDrag (false, xpos, (scroll_height - text_height), xpos, ypos);
		}
	};
	// -- StopDrag
	container_mc.onRelease = container_mc.onReleaseOutside = function () {
		dragin = false;
		cursor_mc.gotoAndStop ("normal");
		container_mc.stopDrag ();};
};
// -- animación inicio:(muestra funcionamiento scroll)
tweenHelp = function () {
	Mouse.hide ();
	// -- inicio animación: subir texto
	container_mc.ySlideTo (ypos, (0.5), "easeOutExpo");
	container_mc.onTweenComplete = function () {
		// -- fin animación, cambiar mano a normal, enviar mano final de texto visible
		delete cursor_mc.onEnterFrame;
		cursor_mc.gotoAndStop ("normal");
		// -- enviar cursor abajo
		cursor_mc.ySlideTo ((scroll_height), (0.5), "easeOutExpo");
		// -- terminada animación bajar cursor
		cursor_mc.onTweenComplete = function () {
			// -- mostrar cursor según donde esté situado
			Mouse.show ();
			onMouseMove ();
		};
	};
	// -- cerrar mano
	cursor_mc.gotoAndStop ("drag");
	cursor_mc._visible = true;
	// -- posicionar _x cursor mano en la animación
	cursor_mc._x = (xpos + (scroll_width / 2));
	// -- posicionar _y cursor mano en la animación
	// --(irá cambiando conforme container_mc mdifica su posición _Y (sube)
	cursor_mc.onEnterFrame = function () {
		cursor_mc._y = container_mc._y;
	};
};
//
myLoadVars = new LoadVars ();
myLoadVars.onLoad = function (succes:Boolean) {
	if (succes) {
		// -- mostrar texto
		showScroll ();
		// -- enmascarar texto
		maskScroll ();
		// -- eventos drag
		dragScroll ();
		// -- animación inicio:(muestra el funcionamiento del scroll)
		tweenHelp ();
	}
};
myLoadVars.load ("data.txt");